Only other parameters can be referenced in parameter default values

[martyh888]

I have search but cannot find out how to get this to work

I am trying to get an IP from an already existing resource and then inject it into a param array that I then use to feed into a module. I am not sure if this is supported and may have to revert to hard coding these variables but thought it would be great if it does work. Please see below code with the error I get when in vscode

resource pip 'Microsoft.Network/publicIPAddresses@2020-11-01' existing = {
  name: 'myDynamicPublic'
  scope: resourceGroup('rgPublicIPs')
}
output testIP string = pip.id

param trafficManagers array = [
  {
    name: 'test-com' 
    endPoints: [
      {
        name: 'IP1'
        targetResourceId: pip.id
        target: 'xx'
     }
   ]
  }]

I have tried both using the Output variable or the pip.id inside a param but this will not work I receive the error

This symbol cannot be referenced here. Only other parameters can be referenced in parameter default values.

[anthony-c-martin]

This is unfortunately not supported. If you're calling this from another module, your best option would be to pass the id in as a separate parameter:

• parent.bicep

  resource pip 'Microsoft.Network/publicIPAddresses@2020-11-01' existing = {
    name: 'myDynamicPublic'
    scope: resourceGroup('rgPublicIPs')
  }
  
  module trafficManager './trafficManager.bicep' = {
    name: 'trafficManager'
    params: {
      pipId: pip.id
    }
  }

• trafficManager.bicep

  param pipId string
  param trafficManagers array = [
    {
      name: 'test-com'
      endPoints: [
        {
          name: 'IP1'
          targetResourceId: pipId
          target: 'xx'
        }
      ]
    }
  ]

[martyh888]

The only issue with this was that it won't work with my looped set of values. I was trying to create all my Traffic Managers from 1 array. I may need to separate them given the follow up issue I am having with endpoints and how Traffic Manager works