forked from tcobbs/ldview
-
Notifications
You must be signed in to change notification settings - Fork 0
/
LDViewA.iss
123 lines (113 loc) · 11.9 KB
/
LDViewA.iss
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
; LDView setup script.
; NOTE: this script requires Inno Setup Preprocessor (ISPP).
; To download and install ISPP, get the Inno Setup QuickStart Pack from:
; http://www.jrsoftware.org/isdl.php#qsp
#define AppFilename 'Build\Release ANSI\LDViewA.exe'
#define SetupFilename(str Filename) GetVersionComponents(Filename, Local[0], Local[1], Local[2], Local[3]), "LDView-" + Str(Local[0]) + Str(Local[1]) + (Local[2] < 10 ? '0' : '') + Str(Local[2]) + "-Legacy"
#define AppVerName GetFileDescription(AppFilename) + ' ' + GetFileVersionString(AppFilename)
#define LegacyAppVerName AppVerName + ' Legacy'
#define IntallDescription LegacyAppVerName + ' Setup'
#define AppVersion GetVersionNumbersString(AppFilename)
[Setup]
AppName=LDView
AppVerName={#LegacyAppVerName}
AppVersion={#AppVersion}
VersionInfoVersion={#AppVersion}
VersionInfoDescription={#IntallDescription}
VersionInfoCopyright={#GetFileCopyright(AppFilename)}
OutputBaseFilename={#SetupFilename(AppFilename)}
SourceDir=.
AppPublisher=Travis Cobbs
AppPublisherURL=https://tcobbs.github.io/ldview/
AppSupportURL=https://tcobbs.github.io/ldview/
AppUpdatesURL=https://tcobbs.github.io/ldview/Downloads.html
Compression=lzma
DefaultDirName={commonpf}\LDView
DefaultGroupName=LDView
OutputDir=Setup
AllowNoIcons=yes
LicenseFile=License.txt
SetupIconFile=Icons\LDViewIcon.ico
ChangesAssociations=yes
UsedUserAreasWarning=no
[Tasks]
Name: desktopicon; Description: Create a &desktop icon; GroupDescription: Additional icons:; Flags: unchecked
Name: quicklaunchicon; Description: Create a &Quick Launch icon; GroupDescription: Additional icons:; Flags: unchecked
Name: screensaver; Description: Install LDView as a screen saver; GroupDescription: Screen Saver:
Name: registerfiles; Description: Use LDView to open LDraw models; GroupDescription: File Associations:; Flags: unchecked
Name: thumbnails; Description: Use LDView to generate thumbnails in Windows Explorer; GroupDescription: Explorer Thumbnails:; Flags: unchecked
Name: prefsets; Description: Install preset Preference Sets; GroupDescription: Preference Sets:
[Files]
Source: Build\Release ANSI\LDViewA.exe; DestDir: {app}; Flags: ignoreversion
Source: license.txt; DestDir: {app}; Flags: ignoreversion
; NOTE: The first Readme.txt is for everything prior to Windows Vista, and can
; be shown at the end of the installation. However, since in Vista that
; would launch Notepad with the same security permissions as the
; installer, we won't let the user view it from the installer there.
Source: Readme.txt; DestDir: {app}; Flags: ignoreversion isreadme; OnlyBelowVersion: 0,6
Source: Readme.txt; DestDir: {app}; Flags: ignoreversion; MinVersion: 0,6
Source: ChangeHistory.html; DestDir: {app}; Flags: ignoreversion
Source: Help.html; DestDir: {app}; Flags: ignoreversion
Source: m6459.ldr; DestDir: {app}; Flags: ignoreversion
Source: 8464.mpd; DestDir: {app}; Flags: ignoreversion
Source: LDExporter\LGEO.xml; DestDir: {app}; Flags: ignoreversion
Source: Help\LDView.hlp; DestDir: {app}; Flags: ignoreversion
Source: LDView Home Page.url; DestDir: {app}; Flags: ignoreversion
Source: Build\Release ANSI\LDViewA.exe; DestDir: {sys}; DestName: LDViewA.scr; Flags: ignoreversion restartreplace; Tasks: screensaver
Source: Build\Release ANSI\LDViewThumbsA.dll; DestDir: {app}; Flags: ignoreversion restartreplace regserver; Tasks: thumbnails
; NOTE: Don't use "Flags: ignoreversion" on any shared system files
[Icons]
Name: {group}\LDView; Filename: {app}\LDViewA.exe
Name: {group}\LDView Home Page; Filename: {app}\LDView Home Page.url; IconFilename: {app}\LDViewA.exe
Name: {group}\Uninstall LDView; Filename: {uninstallexe}
Name: {commondesktop}\LDView; Filename: {app}\LDViewA.exe; Tasks: desktopicon
Name: {userappdata}\Microsoft\Internet Explorer\Quick Launch\LDView; Filename: {app}\LDViewA.exe; Tasks: quicklaunchicon
[Run]
; NOTE: The OnlyBelowVersion flag below prevents this from showing up in Windows
; Vista. If it did show up in Vista, LDView would be executed with the
; same security permissions as the installer, and that's considered to be
; a bad thing there.
Filename: {app}\LDViewA.exe; Parameters: """{app}\m6459.ldr"""; Description: Launch LDView; Flags: nowait postinstall skipifsilent; OnlyBelowVersion: 0,6
[Registry]
Root: HKLM; Subkey: SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\LDViewA.exe; ValueType: string; ValueName: ; ValueData: {app}\LDViewA.exe; Flags: uninsdeletekey noerror
Root: HKCR; Subkey: Applications\LDViewA.exe; ValueType: string; ValueName: ; ValueData: LDView; Flags: uninsdeletekey
Root: HKCR; Subkey: Applications\LDViewA.exe\shell\open\command; ValueType: string; ValueName: ; ValueData: """{app}\LDViewA.exe"" ""%1"""; Tasks: registerfiles
Root: HKCR; Subkey: .ldr; ValueType: string; ValueName: ; ValueData: LDView.ldr; Flags: uninsdeletevalue; Tasks: registerfiles
Root: HKCR; Subkey: LDView.ldr; ValueType: string; ValueName: ; ValueData: LDraw Model; Flags: uninsdeletekey; Tasks: registerfiles
Root: HKCR; Subkey: LDView.ldr\DefaultIcon; ValueType: string; ValueName: ; ValueData: {app}\LDViewA.exe,1; Tasks: registerfiles
Root: HKCR; Subkey: LDView.ldr\shell\open\command; ValueType: string; ValueName: ; ValueData: """{app}\LDViewA.exe"" ""%1"""; Tasks: registerfiles
Root: HKCR; Subkey: .mpd; ValueType: string; ValueName: ; ValueData: LDView.mpd; Flags: uninsdeletevalue; Tasks: registerfiles
Root: HKCR; Subkey: LDView.mpd; ValueType: string; ValueName: ; ValueData: LDraw Multi-Part Dat; Flags: uninsdeletekey; Tasks: registerfiles
Root: HKCR; Subkey: LDView.mpd\DefaultIcon; ValueType: string; ValueName: ; ValueData: {app}\LDViewA.exe,2; Tasks: registerfiles
Root: HKCR; Subkey: LDView.mpd\shell\open\command; ValueType: string; ValueName: ; ValueData: """{app}\LDViewA.exe"" ""%1"""; Tasks: registerfiles
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast; ValueType: string; ValueName: _SessionPlaceholder; ValueData: DO NOT DELETE.; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast; ValueType: dword; ValueName: SortTransparent; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast; ValueType: dword; ValueName: DrawLightDats; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast; ValueType: dword; ValueName: PerformSmoothing; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast; ValueType: dword; ValueName: TextureStuds; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: string; ValueName: _SessionPlaceholder; ValueData: DO NOT DELETE.; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: dword; ValueName: SortTransparent; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: dword; ValueName: DrawLightDats; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: dword; ValueName: PerformSmoothing; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: dword; ValueName: TextureStuds; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: string; ValueName: FOV; ValueData: 20; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: dword; ValueName: Seams; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: dword; ValueName: ShowHighlightLines; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: dword; ValueName: ConditionalHighlights; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: dword; ValueName: SubduedLighting; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: dword; ValueName: UseSpecular; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Fast with Edges; ValueType: dword; ValueName: Lighting; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality; ValueType: string; ValueName: _SessionPlaceholder; ValueData: DO NOT DELETE.; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality; ValueType: dword; ValueName: LineSmoothing; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality; ValueType: dword; ValueName: UseQualityLighting; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality; ValueType: dword; ValueName: UseQualityStuds; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality with Edges; ValueType: string; ValueName: _SessionPlaceholder; ValueData: DO NOT DELETE.; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality with Edges; ValueType: dword; ValueName: LineSmoothing; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality with Edges; ValueType: dword; ValueName: UseQualityLighting; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality with Edges; ValueType: dword; ValueName: UseQualityStuds; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality with Edges; ValueType: string; ValueName: FOV; ValueData: 20; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality with Edges; ValueType: dword; ValueName: Seams; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality with Edges; ValueType: dword; ValueName: ShowHighlightLines; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality with Edges; ValueType: dword; ValueName: ConditionalHighlights; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality with Edges; ValueType: dword; ValueName: SubduedLighting; ValueData: $00000001; Flags: createvalueifdoesntexist; Tasks: prefsets
Root: HKCU; SubKey: Software\Travis Cobbs\LDView\Sessions\LDView Preset - Quality with Edges; ValueType: dword; ValueName: UseSpecular; ValueData: $00000000; Flags: createvalueifdoesntexist; Tasks: prefsets